/*
   SimoneT 2D games Shader v 1.15

   Copyright (C) 2016 SimoneT - simone1tarditi@gmail.com

   part of the code taken from "Directional Cubic Convolution Interpolation"
   created by Dengwen Zhou and Xiaoliu Shen.

   https://en.wikipedia.org/wiki/Directional_Cubic_Convolution_Interpolation

   de Blur, 4xGLSoft lite - Copyright (C) 2016 guest(r) - guest.r@gmail.com

   This program is free software; you can redistribute it and/or
   modify it under the terms of the GNU General Public License
   as published by the Free Software Foundation; either version 2
   of the License, or (at your option) any later version.

   This program is distributed in the hope that it will be useful,
   but WITHOUT ANY WARRANTY; without even the implied warranty of
   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
   GNU General Public License for more details.

   You should have received a copy of the GNU General Public License
   along with this program; if not, write to the Free Software
   Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
    
*/

uniform sampler2D OGL2Texture;
uniform vec4 OGL2Size;
uniform vec4 OGL2InvSize;
uniform vec4 OGL2Param;

const   vec2 Size2D    = vec2( 2048, 1024 );
const   vec2 InvSize2D = vec2(1.0/2048,1.0/1024);
const   vec2 Size3D    = vec2( 4096, 2048 );
const   vec2 InvSize3D = vec2(1.0/4096,1.0/2048);
const   vec3 ones = vec3(1.0,1.0,1.0);
const	vec4 exp = vec4(30.0);	
const	vec4 yx = vec4(1.0/4096,1.0/2048,-1.0/4096,-1.0/2048);
const	vec4 xy = vec4(1.0/2048,1.0/1024,-1.0/2048,-1.0/1024);
const   vec3 decim = vec3(0.001,0.001,0.001);

float Cdistance(vec3 c1, vec3 c2){

	return dot(abs(c1 - c2),ones);

}
 
vec3 Interpolate( vec3 a, vec3 b, vec3 c, vec3 d ) {

	return (( a + b ) * 10.0 +  c + d ) / 22.0;

}

vec3 Diagonal( vec2 coord, vec2 texSize, vec2 shift ) {

	vec2 TexCoord = (floor(coord*texSize)+0.5)*shift;

	vec3 C00 = texture2D(OGL2Texture, TexCoord - shift * 2.0            ).rgb;
	vec3 C01 = texture2D(OGL2Texture, TexCoord - shift * vec2( 1.0, 2.0)).rgb;
	vec3 C02 = texture2D(OGL2Texture, TexCoord - shift * vec2( 0.0, 2.0)).rgb;
	vec3 C03 = texture2D(OGL2Texture, TexCoord - shift * vec2(-1.0, 2.0)).rgb;
	vec3 C04 = texture2D(OGL2Texture, TexCoord - shift * vec2(-2.0, 2.0)).rgb;

	vec3 C05 = texture2D(OGL2Texture, TexCoord - shift * vec2( 2.0, 1.0)).rgb;
	vec3 C06 = texture2D(OGL2Texture, TexCoord - shift                  ).rgb;
	vec3 C07 = texture2D(OGL2Texture, TexCoord - shift * vec2( 0.0, 1.0)).rgb;
	vec3 C08 = texture2D(OGL2Texture, TexCoord - shift * vec2(-1.0, 1.0)).rgb;
	vec3 C09 = texture2D(OGL2Texture, TexCoord - shift * vec2(-2.0, 1.0)).rgb;

	vec3 C10 = texture2D(OGL2Texture, TexCoord - shift * vec2( 2.0, 0.0)).rgb;
	vec3 C11 = texture2D(OGL2Texture, TexCoord - shift * vec2( 1.0, 0.0)).rgb;
	vec3 C12 = texture2D(OGL2Texture, TexCoord                          ).rgb;
	vec3 C13 = texture2D(OGL2Texture, TexCoord + shift * vec2( 1.0, 0.0)).rgb;
	vec3 C14 = texture2D(OGL2Texture, TexCoord + shift * vec2( 2.0, 0.0)).rgb;

	vec3 C15 = texture2D(OGL2Texture, TexCoord + shift * vec2(-2.0, 1.0)).rgb;
	vec3 C16 = texture2D(OGL2Texture, TexCoord + shift * vec2(-1.0, 1.0)).rgb;
	vec3 C17 = texture2D(OGL2Texture, TexCoord + shift * vec2( 0.0, 1.0)).rgb;
	vec3 C18 = texture2D(OGL2Texture, TexCoord + shift                  ).rgb;
	vec3 C19 = texture2D(OGL2Texture, TexCoord + shift * vec2( 2.0, 1.0)).rgb;

	vec3 C20 = texture2D(OGL2Texture, TexCoord + shift * vec2(-2.0, 2.0)).rgb;
	vec3 C21 = texture2D(OGL2Texture, TexCoord + shift * vec2(-1.0, 2.0)).rgb;
	vec3 C22 = texture2D(OGL2Texture, TexCoord + shift * vec2( 0.0, 2.0)).rgb;
	vec3 C23 = texture2D(OGL2Texture, TexCoord + shift * vec2( 1.0, 2.0)).rgb;
	vec3 C24 = texture2D(OGL2Texture, TexCoord + shift * 2.0            ).rgb;

	float C03C09 = Cdistance(C03,C09);
	float C02C08 = Cdistance(C02,C08);
	float C08C14 = Cdistance(C08,C14);
	float C01C07 = Cdistance(C01,C07);
	float C07C13 = Cdistance(C07,C13);
	float C13C19 = Cdistance(C13,C19);
	float C00C06 = Cdistance(C00,C06);
	float C06C12 = Cdistance(C06,C12);
	float C12C18 = Cdistance(C12,C18);
	float C18C24 = Cdistance(C18,C24);
	float C05C11 = Cdistance(C05,C11);
	float C11C17 = Cdistance(C11,C17);
	float C17C23 = Cdistance(C17,C23);
	float C10C16 = Cdistance(C10,C16);
	float C16C22 = Cdistance(C16,C22);
	float C15C21 = Cdistance(C15,C21);

	vec4 d01 = vec4(
	C02C08 + C01C07 + C07C13 + C00C06 + C06C12 + C12C18 + C05C11 + C11C17 + C10C16,
	C03C09 + C02C08 + C08C14 + C01C07 + C07C13 + C13C19 + C06C12 + C12C18 + C11C17,
	C07C13 + C06C12 + C12C18 + C05C11 + C11C17 + C17C23 + C10C16 + C16C22 + C15C21,
	C08C14 + C07C13 + C13C19 + C06C12 + C12C18 + C18C24 + C11C17 + C17C23 + C16C22);

	d01 = pow(d01,exp)+1.0;

	float C01C05 = Cdistance(C01,C05);
	float C02C06 = Cdistance(C02,C06);
	float C06C10 = Cdistance(C06,C10);
	float C03C07 = Cdistance(C03,C07);
	float C07C11 = Cdistance(C07,C11);
	float C11C15 = Cdistance(C11,C15);
	float C04C08 = Cdistance(C04,C08);
	float C08C12 = Cdistance(C08,C12);
	float C12C16 = Cdistance(C12,C16);
	float C16C20 = Cdistance(C16,C20);
	float C09C13 = Cdistance(C09,C13);
	float C13C17 = Cdistance(C13,C17);
	float C17C21 = Cdistance(C17,C21);
	float C14C18 = Cdistance(C14,C18);
	float C18C22 = Cdistance(C18,C22);
	float C19C23 = Cdistance(C19,C23);

	vec4 d02 = vec4(
	C01C05 + C02C06 + C06C10 + C03C07 + C07C11 + C11C15 + C08C12 + C12C16 + C13C17,
	C02C06 + C03C07 + C07C11 + C04C08 + C08C12 + C12C16 + C09C13 + C13C17 + C14C18,
	C06C10 + C07C11 + C11C15 + C08C12 + C12C16 + C16C20 + C13C17 + C17C21 + C18C22,
	C07C11 + C08C12 + C12C16 + C09C13 + C13C17 + C17C21 + C14C18 + C18C22 + C19C23);

	d02 = pow(d02,exp)+1.0;

	vec4 w01 = 1.0 / d01;
	vec4 w02 = 1.0 / d02;
	vec4 w03 = w01 + w02;
	     w03 = 1.0 / w03;

	vec4 weight01 = w01 * w03;
	vec4 weight02 = w02 * w03;

	vec3 DR0 = Interpolate( C06, C12, C00, C18 ); 
	vec3 UR0 = Interpolate( C07, C11, C03, C15 ); 

	vec3 DR1 = Interpolate( C07, C13, C01, C19 ); 
	vec3 UR1 = Interpolate( C08, C12, C04, C16 ); 

	vec3 DR2 = Interpolate( C11, C17, C05, C23 ); 
	vec3 UR2 = Interpolate( C12, C16, C08, C20 ); 

	vec3 DR3 = Interpolate( C12, C18, C06, C24 ); 
	vec3 UR3 = Interpolate( C13, C17, C09, C21 ); 

	vec2 frac = fract(gl_TexCoord[0].xy*texSize);

	vec3 sum0 = DR0 * weight01.x + UR0 * weight02.x; 
	vec3 sum1 = DR1 * weight01.y + UR1 * weight02.y;
	vec3 sum2 = DR2 * weight01.z + UR2 * weight02.z;
	vec3 sum3 = DR3 * weight01.w + UR3 * weight02.w;

	return mix(mix(sum0,sum1,frac.x),mix(sum2,sum3,frac.x),frac.y);
 
}

//	4xGLSoft lite code

vec3 lite4xGLSoft(vec2 texcoord) {

	vec3 c11 = texture2D(OGL2Texture, texcoord        ).rgb; 
	vec3 c00 = texture2D(OGL2Texture, texcoord + xy.zw).rgb; 
	vec3 c20 = texture2D(OGL2Texture, texcoord + xy.xw).rgb; 
	vec3 c22 = texture2D(OGL2Texture, texcoord + xy.xy).rgb; 
	vec3 c02 = texture2D(OGL2Texture, texcoord + xy.zy).rgb; 
	vec3 s00 = texture2D(OGL2Texture, texcoord + yx.zw).rgb; 
	vec3 s20 = texture2D(OGL2Texture, texcoord + yx.xw).rgb; 
	vec3 s22 = texture2D(OGL2Texture, texcoord + yx.xy).rgb; 
	vec3 s02 = texture2D(OGL2Texture, texcoord + yx.zy).rgb; 

	float d1=dot(abs(c00-c22),ones)+0.001;
	float d2=dot(abs(c20-c02),ones)+0.001;
	float m1=dot(abs(s00-s22),ones)+0.001;
	float m2=dot(abs(s02-s20),ones)+0.001;

	vec3 t2=(d1*(c20+c02)+d2*(c00+c22))/(2.0*(d1+d2));
	
	return .25*(c11+t2+(m2*(s00+s22)+m1*(s02+s20))/(m1+m2));

}

//      de Blur code

vec3 deBlur(vec3 c11) {

	vec2 dx  = vec2(xy.x, 0.0);
	vec2 dy  = vec2( 0.0,xy.y);
	vec2 g1  = xy.xy;
	vec2 g2  = vec2(xy.z,xy.y);

	vec3 C0 = lite4xGLSoft(gl_TexCoord[0].xy-g1); 
	vec3 C1 = lite4xGLSoft(gl_TexCoord[0].xy-dy);
	vec3 C2 = lite4xGLSoft(gl_TexCoord[0].xy-g2);
	vec3 C3 = lite4xGLSoft(gl_TexCoord[0].xy-dx);
	vec3 C4 = lite4xGLSoft(gl_TexCoord[0].xy   );
	vec3 C5 = lite4xGLSoft(gl_TexCoord[0].xy+dx);
	vec3 C6 = lite4xGLSoft(gl_TexCoord[0].xy+g2);
	vec3 C7 = lite4xGLSoft(gl_TexCoord[0].xy+dy);
	vec3 C8 = lite4xGLSoft(gl_TexCoord[0].xy+g1);

	vec3 mn1 = min(min(C0,C1),C2);
	vec3 mn2 = min(min(C3,C4),C5);
	vec3 mn3 = min(min(C6,C7),C8);
	vec3 mx1 = max(max(C0,C1),C2);
	vec3 mx2 = max(max(C3,C4),C5);
	vec3 mx3 = max(max(C6,C7),C8);
 
	mn1 = min(min(mn1,mn2),mn3);
	mx1 = max(max(mx1,mx2),mx3);
 
	vec3 dif1 = abs(c11-mn1) + 0.001*ones;
	vec3 dif2 = abs(c11-mx1) + 0.001*ones;
 
	float filterparam = 2.0 + 2.0 * OGL2Param.z; // de Blur control

	dif1=vec3(pow(dif1.x,filterparam),pow(dif1.y,filterparam),pow(dif1.z,filterparam));
	dif2=vec3(pow(dif2.x,filterparam),pow(dif2.y,filterparam),pow(dif2.z,filterparam));
 
	c11.r = (dif1.x*mx1.x + dif2.x*mn1.x)/(dif1.x + dif2.x);
	c11.g = (dif1.y*mx1.y + dif2.y*mn1.y)/(dif1.y + dif2.y);
	c11.b = (dif1.z*mx1.z + dif2.z*mn1.z)/(dif1.z + dif2.z);

	return c11;

}

void main()
{

	gl_FragColor.rgb = deBlur(Diagonal( gl_TexCoord[0].xy, Size2D, InvSize2D ));

}
