/* AA shader v2.o

   Copyright (C) 2006 guest(r) - guest.r@gmail.com

   This program is free software; you can redistribute it and/or
   modify it under the terms of the GNU General Public License
   as published by the Free Software Foundation; either version 2
   of the License, or (at your option) any later version.

   This program is distributed in the hope that it will be useful,
   but WITHOUT ANY WARRANTY; without even the implied warranty of
   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
   GNU General Public License for more details.

   You should have received a copy of the GNU General Public License
   along with this program; if not, write to the Free Software
   Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA.

*/

uniform sampler2D OGL2Texture;

void main()
{
    vec3 c00 = texture2D(OGL2Texture, gl_TexCoord[5].xy).xyz;
    vec3 c10 = texture2D(OGL2Texture, gl_TexCoord[1].xy).xyz;
    vec3 c20 = texture2D(OGL2Texture, gl_TexCoord[2].zw).xyz;
    vec3 c01 = texture2D(OGL2Texture, gl_TexCoord[3].xy).xyz;
    vec3 c11 = texture2D(OGL2Texture, gl_TexCoord[0].xy).xyz;
    vec3 c21 = texture2D(OGL2Texture, gl_TexCoord[4].xy).xyz;
    vec3 c02 = texture2D(OGL2Texture, gl_TexCoord[1].zw).xyz;
    vec3 c12 = texture2D(OGL2Texture, gl_TexCoord[2].xy).xyz;
    vec3 c22 = texture2D(OGL2Texture, gl_TexCoord[6].xy).xyz;
    vec3 dt = vec3(1.0, 1.0, 1.0);

    float d1 = dot(abs(c00 - c22), dt) + 0.0001;
    float d2 = dot(abs(c20 - c02), dt) + 0.0001;
    float hl = dot(abs(c01 - c21), dt) + 0.0001;
    float vl = dot(abs(c10 - c12), dt) + 0.0001;

    float md = d1 + d2;
    float mc = hl + vl;
    hl *= md;
    vl *= md;
    d1 *= mc;
    d2 *= mc;

    float ww = d1 + d2 + hl + vl;

    gl_FragColor.xyz = (hl * (c10 + c12) + vl * (c01 + c21) + d1 * (c20 + c02) + d2 * (c00 + c22) + ww * c11) / (3.0 * ww);
}
