// 4x BRZ shader (fast version by guest.r)
// Copyright (C) 2014-2016 DeSmuME team
//
// This file is free software: you can redistribute it and/or modify
// it under the terms of the GNU General Public License as published by
// the Free Software Foundation, either version 2 of the License, or
// (at your option) any later version.
//
// This file is distributed in the hope that it will be useful,
// but WITHOUT ANY WARRANTY; without even the implied warranty of
// MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
// GNU General Public License for more details.
//
// You should have received a copy of the GNU General Public License
// along with the this software.  If not, see <http://www.gnu.org/licenses/>.


/*
   Hyllian's Data Dependent Triangulation Shader



   Copyright (C) 2011-2012 Hyllian/Jararaca - sergiogdb@gmail.com 

   This program is free software; you can redistribute it and/or
   modify it under the terms of the GNU General Public License
   as published by the Free Software Foundation; either version 2
   of the License, or (at your option) any later version.

   This program is distributed in the hope that it will be useful,
   but WITHOUT ANY WARRANTY; without even the implied warranty of
   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
   GNU General Public License for more details.

   You should have received a copy of the GNU General Public License
   along with this program; if not, write to the Free Software
   Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA.
*/

// combined by guest.r


uniform sampler2D OGL2Texture;
uniform vec4 OGL2Param;


vec2 size = vec2(4096.0,2048.0);


const vec3 dtt = vec3(65536.0,255.0,1.0);



float reduce(vec3 color)

{

	return dot(color, dtt);

} 


vec3 bilinear(float p, float q, vec3 A, vec3 B, vec3 C, vec3 D)

{

	return ((1-p)*(1-q)*A + p*(1-q)*B + (1-p)*q*C + p*q*D);

} 


const   vec2 OGLSize    = vec2( 1024.0, 512.0);
const   vec2 OGLInvSize = vec2( 0.0009765625, 0.001953125); 
const   vec3 Y          = vec3(0.299, 0.587, 0.114);

#define BLEND_NONE 0
#define BLEND_NORMAL 1
#define BLEND_DOMINANT 2
#define LUMINANCE_WEIGHT 1.0
#define EQUAL_COLOR_TOLERANCE 30.0/255.0
#define STEEP_DIRECTION_THRESHOLD 2.2
#define DOMINANT_DIRECTION_THRESHOLD 3.6


float DistYCbCr1(const vec3 pixA, const vec3 pixB)
{
	const vec3 w = vec3(0.2627, 0.6780, 0.0593);
	const float scaleB = 0.5 / (1.0 - w.b);
	const float scaleR = 0.5 / (1.0 - w.r);
	vec3 diff = pixA - pixB;
	float Y = dot(diff, w);
	float Cb = scaleB * (diff.b - Y);
	float Cr = scaleR * (diff.r - Y);
	
	return sqrt( ((LUMINANCE_WEIGHT * Y) * (LUMINANCE_WEIGHT * Y)) + (Cb * Cb) + (Cr * Cr) );
}

float DistYCbCr(const vec3 pixA, const vec3 pixB)
{
	return dot(abs(pixA-pixB), Y);
}
	
bool IsPixEqual(const vec3 pixA, const vec3 pixB)
{
	return (DistYCbCr(pixA, pixB) < EQUAL_COLOR_TOLERANCE);
}

bool IsBlendingNeeded(const ivec4 blend)
{
	return any(notEqual(blend, ivec4(BLEND_NONE)));
}

	// Output Pixel Mapping:  06|07|08|09
	//                        05|00|01|10
	//                        04|03|02|11
	//                        15|14|13|12


vec3 xBRZ4x (sampler2D OGL2Texture, vec2 texcoord) {

    vec2 f = fract(texcoord*OGLSize);
    vec2 TexCoord_0 = texcoord-f*OGLInvSize + 0.5*OGLInvSize;

    vec2 siggn = vec2(1.0,1.0);

    if (f.x >= 0.5) { f.x = 1.0 - f.x; siggn.x = -1.0; }
    if (f.y >= 0.5) { f.y = 1.0 - f.y; siggn.y = -1.0; }

    vec2 dx         = vec2( 0.0009765625, 0.0)*siggn.x;
    vec2 dy         = vec2( 0.0, 0.001953125 )*siggn.y;
    vec2 x2         = vec2( 0.001953125 , 0.0)*siggn.x;
    vec2 y2         = vec2( 0.0 , 0.00390625 )*siggn.y;
    vec4 xy         = vec4( 0.0009765625, 0.001953125,-0.0009765625,-0.001953125)*siggn.xyxy;  
    vec4 zw         = vec4( 0.001953125 , 0.001953125,-0.001953125 ,-0.001953125)*siggn.xyxy;  
    vec4 wz         = vec4( 0.0009765625, 0.00390625 ,-0.0009765625,-0.00390625 )*siggn.xyxy;  

    vec3 src[25];

    src[ 6] = texture2D(OGL2Texture, TexCoord_0 + xy.zw ).xyz;
    src[ 7] = texture2D(OGL2Texture, TexCoord_0     -dy ).xyz;
    src[ 8] = texture2D(OGL2Texture, TexCoord_0 + xy.xw ).xyz;
    src[ 5] = texture2D(OGL2Texture, TexCoord_0 - dx    ).xyz;
    src[ 0] = texture2D(OGL2Texture, TexCoord_0         ).xyz;
    src[ 1] = texture2D(OGL2Texture, TexCoord_0 + dx    ).xyz;
    src[ 4] = texture2D(OGL2Texture, TexCoord_0 + xy.zy ).xyz;
    src[ 3] = texture2D(OGL2Texture, TexCoord_0     +dy ).xyz;
    src[ 2] = texture2D(OGL2Texture, TexCoord_0 + xy.xy ).xyz;
    src[21] = texture2D(OGL2Texture, TexCoord_0 + wz.zw ).xyz;
    src[23] = texture2D(OGL2Texture, TexCoord_0 + wz.xw ).xyz;
    src[19] = texture2D(OGL2Texture, TexCoord_0 + zw.zw ).xyz;
    src[17] = texture2D(OGL2Texture, TexCoord_0 + zw.zy ).xyz;
    src[ 9] = texture2D(OGL2Texture, TexCoord_0 + zw.xw ).xyz;
    src[11] = texture2D(OGL2Texture, TexCoord_0 + zw.xy ).xyz;
    src[15] = texture2D(OGL2Texture, TexCoord_0 + wz.zy ).xyz;
    src[13] = texture2D(OGL2Texture, TexCoord_0 + wz.xy ).xyz;
    src[22] = texture2D(OGL2Texture, TexCoord_0 - y2    ).xyz;
    src[18] = texture2D(OGL2Texture, TexCoord_0 - x2    ).xyz;
    src[14] = texture2D(OGL2Texture, TexCoord_0 + y2    ).xyz;
    src[10] = texture2D(OGL2Texture, TexCoord_0 + x2    ).xyz;

		float v[9];
		v[0] = reduce(src[0]);
		v[1] = reduce(src[1]);
		v[2] = reduce(src[2]);
		v[3] = reduce(src[3]);
		v[4] = reduce(src[4]);
		v[5] = reduce(src[5]);
		v[6] = reduce(src[6]);
		v[7] = reduce(src[7]);
		v[8] = reduce(src[8]);
		
		ivec4 blendResult = ivec4(BLEND_NONE);
		// Preprocess corners
		// Pixel Tap Mapping: --|--|--|--|--
		//                    --|--|07|08|--
		//                    --|05|00|01|10
		//                    --|04|03|02|11
		//                    --|--|14|13|--
		
		// Corner (1, 1)
		if ( !((v[0] == v[1] && v[3] == v[2]) || (v[0] == v[3] && v[1] == v[2])) )
		{
			float dist_03_01 = DistYCbCr(src[ 4], src[ 0]) + DistYCbCr(src[ 0], src[ 8]) + DistYCbCr(src[14], src[ 2]) + DistYCbCr(src[ 2], src[10]) + (4.0 * DistYCbCr(src[ 3], src[ 1]));
			float dist_00_02 = DistYCbCr(src[ 5], src[ 3]) + DistYCbCr(src[ 3], src[13]) + DistYCbCr(src[ 7], src[ 1]) + DistYCbCr(src[ 1], src[11]) + (4.0 * DistYCbCr(src[ 0], src[ 2]));
			bool dominantGradient = (DOMINANT_DIRECTION_THRESHOLD * dist_03_01) < dist_00_02;
			blendResult[2] = ((dist_03_01 < dist_00_02) && (v[0] != v[1]) && (v[0] != v[3])) ? ((dominantGradient) ? BLEND_DOMINANT : BLEND_NORMAL) : BLEND_NONE;
		}				
		
		// Pixel Tap Mapping: --|--|--|--|--
		//                    --|06|07|--|--
		//                    18|05|00|01|--
		//                    17|04|03|02|--
		//                    --|15|14|--|--
		// Corner (0, 1)
		if ( !((v[5] == v[0] && v[4] == v[3]) || (v[5] == v[4] && v[0] == v[3])) )
		{
			float dist_04_00 = DistYCbCr(src[17], src[ 5]) + DistYCbCr(src[ 5], src[ 7]) + DistYCbCr(src[15], src[ 3]) + DistYCbCr(src[ 3], src[ 1]) + (4.0 * DistYCbCr(src[ 4], src[ 0]));
			float dist_05_03 = DistYCbCr(src[18], src[ 4]) + DistYCbCr(src[ 4], src[14]) + DistYCbCr(src[ 6], src[ 0]) + DistYCbCr(src[ 0], src[ 2]) + (4.0 * DistYCbCr(src[ 5], src[ 3]));
			bool dominantGradient = (DOMINANT_DIRECTION_THRESHOLD * dist_05_03) < dist_04_00;
			blendResult[3] = ((dist_04_00 > dist_05_03) && (v[0] != v[5]) && (v[0] != v[3])) ? ((dominantGradient) ? BLEND_DOMINANT : BLEND_NORMAL) : BLEND_NONE;
		}
		
		// Pixel Tap Mapping: --|--|22|23|--
		//                    --|06|07|08|09
		//                    --|05|00|01|10
		//                    --|--|03|02|--
		//                    --|--|--|--|--
		// Corner (1, 0)
		if ( !((v[7] == v[8] && v[0] == v[1]) || (v[7] == v[0] && v[8] == v[1])) )
		{
			float dist_00_08 = DistYCbCr(src[ 5], src[ 7]) + DistYCbCr(src[ 7], src[23]) + DistYCbCr(src[ 3], src[ 1]) + DistYCbCr(src[ 1], src[ 9]) + (4.0 * DistYCbCr(src[ 0], src[ 8]));
			float dist_07_01 = DistYCbCr(src[ 6], src[ 0]) + DistYCbCr(src[ 0], src[ 2]) + DistYCbCr(src[22], src[ 8]) + DistYCbCr(src[ 8], src[10]) + (4.0 * DistYCbCr(src[ 7], src[ 1]));
			bool dominantGradient = (DOMINANT_DIRECTION_THRESHOLD * dist_07_01) < dist_00_08;
			blendResult[1] = ((dist_00_08 > dist_07_01) && (v[0] != v[7]) && (v[0] != v[1])) ? ((dominantGradient) ? BLEND_DOMINANT : BLEND_NORMAL) : BLEND_NONE;
		}
		
		// Pixel Tap Mapping: --|21|22|--|--
		//                    19|06|07|08|--
		//                    18|05|00|01|--
		//                    --|04|03|--|--
		//                    --|--|--|--|--
		// Corner (0, 0)
		if ( !((v[6] == v[7] && v[5] == v[0]) || (v[6] == v[5] && v[7] == v[0])) )
		{
			float dist_05_07 = DistYCbCr(src[18], src[ 6]) + DistYCbCr(src[ 6], src[22]) + DistYCbCr(src[ 4], src[ 0]) + DistYCbCr(src[ 0], src[ 8]) + (4.0 * DistYCbCr(src[ 5], src[ 7]));
			float dist_06_00 = DistYCbCr(src[19], src[ 5]) + DistYCbCr(src[ 5], src[ 3]) + DistYCbCr(src[21], src[ 7]) + DistYCbCr(src[ 7], src[ 1]) + (4.0 * DistYCbCr(src[ 6], src[ 0]));
			bool dominantGradient = (DOMINANT_DIRECTION_THRESHOLD * dist_05_07) < dist_06_00;
			blendResult[0] = ((dist_05_07 < dist_06_00) && (v[0] != v[5]) && (v[0] != v[7])) ? ((dominantGradient) ? BLEND_DOMINANT : BLEND_NORMAL) : BLEND_NONE;
		}
		
		vec3 dst[16];
		dst[ 0] = src[0];
		dst[ 5] = src[0];
		dst[ 6] = src[0];
		dst[ 7] = src[0];

		
		// Scale pixel
		if (IsBlendingNeeded(blendResult))
		{			
			float dist_01_04 = DistYCbCr(src[7], src[2]);
			float dist_03_08 = DistYCbCr(src[1], src[6]);
			bool haveShallowLine = (STEEP_DIRECTION_THRESHOLD * dist_01_04 <= dist_03_08) && (v[0] != v[2]) && (v[3] != v[2]);
			bool haveSteepLine   = (STEEP_DIRECTION_THRESHOLD * dist_03_08 <= dist_01_04) && (v[0] != v[6]) && (v[5] != v[6]);
			bool needBlend = (blendResult[1] != BLEND_NONE);
			bool doLineBlend = (  blendResult[1] >= BLEND_DOMINANT ||
						  !((blendResult[0] != BLEND_NONE && !IsPixEqual(src[0], src[2])) ||
							(blendResult[2] != BLEND_NONE && !IsPixEqual(src[0], src[6])) ||
							(IsPixEqual(src[2], src[1]) && IsPixEqual(src[1], src[8]) && IsPixEqual(src[8], src[7]) && IsPixEqual(src[7], src[6]) && !IsPixEqual(src[0], src[8])) ) );
			
			vec3 blendPix = ( DistYCbCr(src[0], src[7]) <= DistYCbCr(src[0], src[1]) ) ? src[7] : src[1];
			dst[ 6] = mix(dst[ 6], blendPix, (needBlend && doLineBlend && haveSteepLine) ? 0.25 : 0.00);
			dst[ 7] = mix(dst[ 7], blendPix, (needBlend && doLineBlend && haveSteepLine) ? 0.75 : 0.00);
			
			
			dist_01_04 = DistYCbCr(src[5], src[8]);
			dist_03_08 = DistYCbCr(src[7], src[4]);
			haveShallowLine = (STEEP_DIRECTION_THRESHOLD * dist_01_04 <= dist_03_08) && (v[0] != v[8]) && (v[1] != v[8]);
			haveSteepLine   = (STEEP_DIRECTION_THRESHOLD * dist_03_08 <= dist_01_04) && (v[0] != v[4]) && (v[3] != v[4]);
			needBlend = (blendResult[0] != BLEND_NONE);
			doLineBlend = (  blendResult[0] >= BLEND_DOMINANT ||
						  !((blendResult[3] != BLEND_NONE && !IsPixEqual(src[0], src[8])) ||
							(blendResult[1] != BLEND_NONE && !IsPixEqual(src[0], src[4])) ||
							(IsPixEqual(src[8], src[7]) && IsPixEqual(src[7], src[6]) && IsPixEqual(src[6], src[5]) && IsPixEqual(src[5], src[4]) && !IsPixEqual(src[0], src[6])) ) );
			
			blendPix = ( DistYCbCr(src[0], src[5]) <= DistYCbCr(src[0], src[7]) ) ? src[5] : src[7];
			dst[ 0] = mix(dst[ 0], blendPix, (needBlend && doLineBlend) ? ((haveShallowLine) ? ((haveSteepLine) ? 1.0/3.0 : 0.25) : ((haveSteepLine) ? 0.25 : 0.00)) : 0.00);
			dst[ 5] = mix(dst[ 5], blendPix, (needBlend) ? ((doLineBlend) ? ((haveSteepLine) ? 1.00 : ((haveShallowLine) ? 0.75 : 0.50)) : 0.08677704501) : 0.00);
			dst[ 6] = mix(dst[ 6], blendPix, (needBlend) ? ((doLineBlend) ? 1.00 : 0.6848532563) : 0.00);
			dst[ 7] = mix(dst[ 7], blendPix, (needBlend) ? ((doLineBlend) ? ((haveShallowLine) ? 1.00 : ((haveSteepLine) ? 0.75 : 0.50)) : 0.08677704501) : 0.00);
			
			
			dist_01_04 = DistYCbCr(src[3], src[6]);
			dist_03_08 = DistYCbCr(src[5], src[2]);
			haveShallowLine = (STEEP_DIRECTION_THRESHOLD * dist_01_04 <= dist_03_08) && (v[0] != v[6]) && (v[7] != v[6]);
			haveSteepLine   = (STEEP_DIRECTION_THRESHOLD * dist_03_08 <= dist_01_04) && (v[0] != v[2]) && (v[1] != v[2]);
			needBlend = (blendResult[3] != BLEND_NONE);
			doLineBlend = (  blendResult[3] >= BLEND_DOMINANT ||
						  !((blendResult[2] != BLEND_NONE && !IsPixEqual(src[0], src[6])) ||
							(blendResult[0] != BLEND_NONE && !IsPixEqual(src[0], src[2])) ||
							(IsPixEqual(src[6], src[5]) && IsPixEqual(src[5], src[4]) && IsPixEqual(src[4], src[3]) && IsPixEqual(src[3], src[2]) && !IsPixEqual(src[0], src[4])) ) );
			
			blendPix = ( DistYCbCr(src[0], src[3]) <= DistYCbCr(src[0], src[5]) ) ? src[3] : src[5];
			dst[ 5] = mix(dst[ 5], blendPix, (needBlend && doLineBlend && haveShallowLine) ? 0.75 : 0.00);
			dst[ 6] = mix(dst[ 6], blendPix, (needBlend && doLineBlend && haveShallowLine) ? 0.25 : 0.00);
		}
		
		vec3 res;

		f = step(0.25, f);
		res = mix( mix(dst[6], dst[7], f.x),
		                        mix(dst[5], dst[0], f.x), f.y );

    return res;
} 


void main()
{
	vec2 pos = fract(gl_TexCoord[0].xy*size)-vec2(0.5, 0.5); // pos = pixel position
	
	vec2 dir = sign(pos); // dir = pixel direction

	vec2 g1 = dir*gl_TexCoord[1].xy;

	vec2 g2 = dir*gl_TexCoord[1].zw; 

	vec3 A = xBRZ4x(OGL2Texture, gl_TexCoord[0].xy          ).xyz; 
	vec3 B = xBRZ4x(OGL2Texture, gl_TexCoord[0].xy + g1     ).xyz; 
	vec3 C = xBRZ4x(OGL2Texture, gl_TexCoord[0].xy      + g2).xyz; 
	vec3 D = xBRZ4x(OGL2Texture, gl_TexCoord[0].xy + g1 + g2).xyz; 

	float a = reduce(A);

	float b = reduce(B);

	float c = reduce(C);

	float d = reduce(D); 

	float p = abs(pos.x);
	
	float q = abs(pos.y);



	float k = distance(pos,g1);

	float l = distance(pos,g2); 

	if (abs(a-d) < abs(b-c))

	{

		if (k < l)

		{

			C = A + D - B;

		}

		else if (k >= l)

		{

			B = A + D - C;

		}

	}

	else if (abs(a-d) > abs(b-c))

	{

		D = B + C - A;

	} 

	gl_FragColor.xyz=bilinear(p, q, A, B, C, D);
}